Полезное для программистов:

Фриланс
Новости
Статьи
   
Рубрики:


Пример компонента HotSpot

Поиск:
Вот пример HotSpot-компонента, основанного на TPanel (небольшая переделка). Управляя событиями MouseDown и MouseUp можно получить эффект резинового контура.

Код
unit Newpanel;

interface
uses WinTypes, Classes, Controls, StdCtrls, ExtCtrls;

type

 tHotSpotClickEvent = procedure(Sender: tObject;
   Button: tMouseButton;
   Shift: tShiftState) of object;

 TNewPanel = class(tPanel)
 private
   fHotSpotClick: tHotSpotClickEvent;
   fHotSpot: tRect;
   fInHotSpot: Boolean;
   function GetHotSpotTop: Word;
   function GetHotSpotLeft: Word;
   function GetHotSpotWidth: Word;
   function GetHotSpotHeight: Word;
   procedure SetHotSpotTop(Value: Word);
   procedure SetHotSpotLeft(Value: Word);
   procedure SetHotSpotWidth(Value: Word);
   procedure SetHotSpotHeight(Value: Word);
 protected
   procedure Paint; override;
   procedure MouseDown(Button: tMouseButton; Shift: tShiftState; X, Y: Integer);
     override;
   procedure MouseUp(Button: tMouseButton; Shift: tShiftState; X, Y: Integer);
     override;
 public
   procedure Click; override;
   property HotSpot: tRect read fHotSpot write fHotSpot;
 published
   property hsTop: Word read GetHotSpotTop write SetHotSpotTop;
   property hsLeft: Word read GetHotSpotLeft write SetHotSpotLeft;
   property hsWidth: Word read GetHotSpotWidth write SetHotSpotWidth;
   property hsHeight: Word read GetHotSpotHeight write SetHotSpotHeight;
   property OnHotSpot: tHotSpotClickEvent read fHotSpotClick write
     fHotSpotClick;
 end;

procedure Register;

implementation
uses WinProcs, Graphics;

procedure Register;
begin
 RegisterComponents('Custom', [TNewPanel]);
end;

procedure TNewPanel.MouseDown(Button: tMouseButton;
 Shift: tShiftState;
 X, Y: Integer);
begin
 if PtInRect(fHotSpot, Point(X, Y)) and
   Assigned(fHotSpotClick) then
   fInHotSpot := True;
 inherited MouseDown(Button, Shift, X, Y);
end;

procedure TNewPanel.MouseUp(Button: tMouseButton;
 Shift: tShiftState;
 X, Y: Integer);
begin
 inherited MouseUp(Button, Shift, X, Y);

 if fInHotSpot then
 begin
   if Assigned(fHotSpotClick) then
     fHotSpotClick(Self, Button, Shift);
   fInHotSpot := False;
 end;
end;

procedure TNewPanel.Click;
begin
 if not fInHotSpot then
   inherited Click;
end;

procedure TNewPanel.Paint;
var
 OldStyle: tPenStyle;
begin
 inherited Paint;

 if csDesigning in ComponentState then
 begin
   OldStyle := Canvas.Pen.Style;
   Canvas.Pen.Style := psDash;
   Canvas.Rectangle(HotSpot.Left, HotSpot.Top, HotSpot.Right, HotSpot.Bottom);
   Canvas.Pen.Style := OldStyle;
 end;
end;

procedure TNewPanel.SetHotSpotTop(Value: Word);
begin
 fHotSpot.Bottom := fHotSpot.Bottom + Value - fHotSpot.Top;
 fHotSpot.Top := Value;
 Paint;
end;

procedure TNewPanel.SetHotSpotLeft(Value: Word);
begin
 fHotSpot.Right := fHotSpot.Right + Value - fHotSpot.Left;
 fHotSpot.Left := Value;
 Paint;
end;

procedure TNewPanel.SetHotSpotWidth(Value: Word);
begin
 fHotSpot.Right := fHotSpot.Left + Value;
 Paint;
end;

procedure TNewPanel.SetHotSpotHeight(Value: Word);
begin
 fHotSpot.Bottom := fHotSpot.Top + Value;
 Paint;
end;

function TNewPanel.GetHotSpotTop: Word;
begin
 Result := fHotSpot.Top
end;

function TNewPanel.GetHotSpotLeft: Word;
begin
 Result := fHotSpot.Left;
end;

function TNewPanel.GetHotSpotWidth: Word;
begin
 Result := fHotSpot.Right - fHotSpot.Left;
end;

function TNewPanel.GetHotSpotHeight: Word;
begin
 Result := fHotSpot.Bottom - fHotSpot.Top;
end;

end.
Автор: Robert Wittig
Сайт: http://delphiworld.narod.ru






Просмотров: 1504

 

 

Новые статьи:


Популярные:
  1. Как сделать цикличным проигрывание MIDI-файла?
  2. Создание AVI файла из рисунков
  3. Как устройство "отключить в данной конфигурации"?
  4. Kто в данный момент присоединен через Сеть?
  5. Как узнать количество доступной памяти?
  6. Как реализовать в RichEdit разноцветный текст?
  7. Как скрыть свое приложение от ProcessViewer
  8. Как программно нажать/скрыть/показ кнопку "Start"?
  9. Модуль работы с ресурсами в PE файлах
10. Функции вызова диалоговых окон выбора
11. Проверка граматики средствами Word'а из Delphi.
12. Модуль для упрощенного вызова сообщений
13. Функции для записи и чтение своих данных в, ЕХЕ- файле
14. Рекурсивный просмотр директорий
15. Network Traffic Monitor
16. Разные модули
17. Универсальная функция для обращения к любым экспортируем функциям DLL
18. Библиотека от VladS
19. Протектор для UPX'а
20. Еще об ICQ, сообщения по контакт листу?
21. Использование открытых интерфейсов
22. Теория и практика использования RTTI
23. Работа с TApplication
24. Примеры использования Drag and Drop для различных визуальных компонентов
25. Что такое порт? Правила для работы с портами
26. Симфония на клавиатуре
27. Загрузка DLL
28. Исправление автоинкремента
29. Взаимодействие с чужими окнами
30. Проверить дубляжи в столбце


 

 

 
 
На главную